A simple module with some "glue code" necessary for using diagrams and GraphViz (http://www.graphviz.org/) in conjunction. GraphViz is great at laying out graphs but terrible at drawing them, so why not let GraphViz do what it is good at, and use a dedicated drawing library for the actual drawing?

In all the following examples we will make use of this example graph:

hex = mkGraph [0..19]
        (   [ (v, (v+1)`mod`6, ()) | v <- [0..5] ]
         ++ [ (v, v+k, ()) | v <- [0..5], k <- [6,12] ]
         ++ [ (2,18,()), (2,19,()), (15,18,()), (15,19,()), (18,3,()), (19,3,()) ]
        )

The easiest thing to do is to just use the provided simpleGraphDiagram function to create a default diagram quickly:

{-# LANGUAGE NoMonomorphismRestriction #-}

import           Diagrams.Backend.Rasterific.CmdLine
import           Diagrams.Prelude
import           Diagrams.TwoD.GraphViz

main = theGraph >>= defaultMain
  where
    theGraph :: IO (Diagram B)
    theGraph = simpleGraphDiagram Dot hex

Here is how we would produce a similar image, but with more control over the specific ways that things are drawn:

{-# LANGUAGE NoMonomorphismRestriction #-}

import           Diagrams.Backend.Rasterific.CmdLine
import           Diagrams.Prelude
import           Diagrams.TwoD.GraphViz

import           Data.GraphViz
import           Data.GraphViz.Commands

graphvizExample1 = do
  hex' <- layoutGraph Dot hex
  let hexDrawing :: Diagram B
      hexDrawing = drawGraph
                     (const $ place (circle 19))
                     (\_ p1 _ p2 _ p -> arrowBetween' (opts p) p1 p2)
                     hex'
      opts p = with & gaps .~ 16 & arrowShaft .~ (unLoc . head $ pathTrails p)
  return (hexDrawing # frame 1)

There are a few quirks to note.

• GraphViz seems to assume the circular nodes have radius 19.
• Note how we draw an arrow for each edge, and use the path computed by GraphViz (which might be curved) to specify the shaft for the arrow.

Here is a slightly modified example, which tells GraphViz not to use any arrowheads on the edges:

{-# LANGUAGE NoMonomorphismRestriction #-}

import           Diagrams.Backend.Rasterific.CmdLine
import           Diagrams.Prelude
import           Diagrams.TwoD.GraphViz

import           Data.GraphViz
import           Data.GraphViz.Attributes.Complete
import           Data.GraphViz.Commands

main = do
  let params :: GraphvizParams Int v e () v
      params = defaultDiaParams
               { fmtEdge = const [arrowTo noArrow] }
  hex' <- layoutGraph' params Dot hex
  let hexDrawing :: Diagram B
      hexDrawing = drawGraph
                     (const $ place (circle 19))
                     (\_ _ _ _ _ p -> stroke p)
                     hex'
  mainWith $ hexDrawing # frame 1

• The type signature on params is unfortunately necessary; otherwise some ambiguity errors arise.
• Note how in this simple case we can just draw the path for each edge directly.